Описание
Указывает, следует ли преобразовывать пустые строки (""), которые используются в программах для заполнения полей типа Text или Memo, в пустые значения (Null).

Значение
Задаваемое или возвращаемое значение является выражением типа Boolean, которое имеет значение True, если пустые строки преобразуются в пустые значения.

Замечания
Данное свойство применимо к базам данных с ядром Microsoft Jet версии 1.x, преобразованным в формат ядра Microsoft Jet версии 2.0 или 3.0
Это свойство автоматически создается ядром базы данных Microsoft Jet при преобразовании базы данных версии 1.x в базу данных версии 2.0 или 3.0. База данных версии 2.0 сохранит это свойство после преобразования в базу данных версии 3.0.
После изменения значения этого свойства необходимо закрыть базу данных и снова открыть ее, чтобы внесенные изменения вступили в действие.
Для увеличения быстродействия измените в программах инструкции, задающие пустые строки в значениях текстовых полей и полей Memo, на инструкции, задающие значения Null, и удалите свойство V1xNullBehavior из семейства Properties.

Пример
Следующая программа преобразует файл базы данных Microsoft Jet версии 1.1 в файл базы данных Microsoft Jet версии 3.0. При преобразовании свойство V1xNullBehavior создается и добавляется в семейство Properties новой базы данных. Для демонстрации изменений печатаются семейства Properties обеих баз данных. И наконец, свойство V1xNullBehavior удаляется. При этом подразумевается, что любые приложения будут преобразованы таким образом, чтобы сохранять в полях типа Text и Memo значения Null вместо пустых строк.
Для выполнения данной процедуры необходимо получить файл базы данных Microsoft Jet версии 1.1 с именем "Nwind11.mdb".

Sub V1xNullBehaviorX()

	Dim dbsNorthwind As Database
	Dim prpLoop As Property

	Set dbsNorthwind = OpenDatabase("Nwind11.mdb")

	With dbsNorthwind
		Debug.Print .Name & ", версии " & .Version
		' Отображает семейство Properties базы данных. 
		For Each prpLoop In .Properties
			On Error Resume Next
			If prpLoop <> "" Then Debug.Print "    " & prpLoop.Name & " = " & prpLoop
			On Error GoTo 0
		Next prpLoop
		.Close
	End With

	DBEngine.CompactDatabase "Nwind11.mdb", "Nwind30.mdb", , dbVersion30

	Set dbsNorthwind = OpenDatabase("Nwind30.mdb")

	With dbsNorthwind
		Debug.Print .Name & ", версии " & .Version

		' Отображает семейство Properties сжатой базы данных. 
		' На свойство V1xNullBehavior нельзя ссылаться в явном виде,
		' т.е. в формате dbsNorthwind.V1xNullBehavior. Однако
		' оно доступно в циклах или в ссылке с помощью 
		' строкового выражения, т.е. в формате 
		' dbsNorthwind.Properties("V1xNullBehavior").
		For Each prpLoop In .Properties
			On Error Resume Next
			If prpLoop <> "" Then Debug.Print "    " & 	prpLoop.Name & " = " & prpLoop
			On Error GoTo 0
		Next prpLoop

		.Properties.Delete "V1xNullBehavior"
		.Close
	End With

End Sub