Шаг 39 - Свойство DefaultCursorDriver

Описание
Задает или возвращает тип драйвера указателя набора записей, используемого в подключении, созданном с помощью метода OpenConnection или OpenDatabase (только в рабочей области ODBCDirect).

Значение
Задаваемое или возвращаемое значение имеет тип данных Long и определяется одной из следующих констант:

Замечания
Значение данного свойства затрагивает только подключения, устанавливаемые после определения этого значения. На существующие подключения значение свойства DefaultCursorDriver не влияет.

Пример
Следующая программа использует метод NextRecordset для просмотра данных составного запроса SELECT. При выполнении таких запросов свойство DefaultCursorDriver должно получить значение dbUseODBCCursor. Метод NextRecordset возвращает значение True, даже если некоторые или все инструкции SELECT не возвращают записей. Значение False будет возвращено только после всех предложений инструкции SQL.

Sub NextRecordsetX()

	Dim wrkODBC As Workspace
	Dim conPubs As Connection
	Dim rstTemp As Recordset
	Dim intCount As Integer
	Dim booNext As Boolean

	' Создает объект Workspace ODBCDirect и открывает объект 
	' Connection. При использовании составных инструкций SQL 
	' значение DefaultCursorDriver является обязательным.
	Set wrkODBC = CreateWorkspace("", "admin", "", dbUseODBC)
	wrkODBC.DefaultCursorDriver = dbUseODBCCursor
	Set conPubs = wrkODBC.OpenConnection("Publishers", , , "ODBC;DATABASE=pubs;UID=sa;PWD=;DSN=Publishers")
	' Создает составную инструкцию SELECT.
	Set rstTemp = conPubs.OpenRecordset("SELECT * " & "FROM authors; " & "SELECT * FROM stores; " & "SELECT * FROM jobs")
	' Делает попытку напечатать результаты каждой из трех 
	' инструкций SELECT.
	booNext = True
	intCount = 1
	With rstTemp
		Do While booNext
			Debug.Print "Содержимое набора записей #" & intCount
			Do While Not .EOF
			Debug.Print , .Fields(0), .Fields(1)
			.MoveNext
			Loop
			booNext = .NextRecordset
			Debug.Print "    rstTemp.NextRecordset = " & 	booNext
			intCount = intCount + 1
		Loop
	End With
	rstTemp.Close
	conPubs.Close
	wrkODBC.Close
End Sub

Предыдущий Шаг | Следующий Шаг | Оглавление
Автор Каев Артем.