Описание
Заносит сведения о подключении к источнику данных ODBC в реестр Windows. Эти сведения необходимы для драйвера ODBC при открытии источника данных ODBC во время сеанса.

DBEngine.RegisterDatabase имяБД, драйвер, скрытие, атрибуты

Параметры
имяБД
Выражение типа String, содержащее имя, используемое в методе OpenDatabase для ссылки на блок сведений о параметрах источника данных. Например, если источником данных является удаленная база данных ODBC, то данный аргумент задает имя сервера.
драйвер
Выражение типа String, задающее имя драйвера ODBC. Имя драйвера не совпадает с именем файла библиотеки динамической компоновки (DLL) драйвера ODBC. Например, "SQL Server" является именем драйвера, а SQLSRVR.dll является именем файла библиотеки. Программное обеспечение ODBC и соответствующий драйвер должны быть заранее установлены в системе.
скрытие
Выражение типа Boolean, имеющее значение True, если не нужно выводить на экран окна диалога драйвера ODBC, запрашивающие необходимые сведения для драйвера, или значение False при необходимости указать вывод окон диалога драйвера ODBC. Если в аргументе скрытие задано значение True, то аргумент атрибуты должен содержать всю необходимую для конкретного драйвера информацию, иначе окна диалога все равно будут выводиться.
атрибуты
Выражение типа String, содержащее список элементов, которые следует добавить в реестр Windows. Элементы, включаемые в строку атрибутов, разделяются символами возврата каретки.

Замечания
Если база данных уже зарегистрирована, т.е. сведения о подключении уже введены в реестр Windows, то при вызове метода RegisterDatabase сведения о подключении будут обновлены.
Если по какой-либо причине метод RegisterDatabase не может быть выполнен, то изменения в реестр Windows не заносятся и возникает ошибка.
Дополнительные сведения о драйверах ODBC, таких как SQL Server, можно найти в файле справочной системы, поставляемой с конкретным драйвером.
Для добавления новых источников данных или для изменения существующих рекомендуется использовать диалоговое окно ODBC Data Sources в окне настройка Windows. Если, однако, по каким то причинам предпочтительнее использовать метод RegisterDatabase, рекомендуется задавать для аргумента скрытие значение True.

Пример
Следующая программа использует метод RegisterDatabase для регистрации источника данных Microsoft SQL Server "Publishers" в реестре Windows.
Лучшим способом создания, изменения или удаления имен источников данных является использование значка "ODBC" панели управления Windows.

Sub RegisterDatabaseX()

	Dim dbsRegister As Database
	Dim strDescription As String
	Dim strAttributes As String
	Dim errLoop As Error

	' Создает строку ключевых слов.
	strDescription = InputBox( "Введите описание " & "регистрируемой базы данных.")
	strAttributes = "Database=pubs" & _
		vbCr & "Description=" & strDescription & vbCr & "OemToAnsi=No" & vbCr & "Server=Server1"
	' Обновляет реестр Windows.
	On Error GoTo Err_Register

	DBEngine.RegisterDatabase "Publishers", "SQL Server", True, strAttributes
	On Error GoTo 0
	MsgBox "Для просмотра изменений вызовите " & "regedit.exe: " & "HKEY_CURRENT_USER\" & 	"Software\ODBC\ODBC.INI"
	Exit Sub
Err_Register:
	' Уведомляет пользователя о любых ошибках, 
	' являющихся  следствием недопустимых данных.
	If DBEngine.Errors.Count > 0 Then
		For Each errLoop In DBEngine.Errors
			MsgBox "Код ошибки: " & errLoop.Number & vbCr & errLoop.Description
		Next errLoop
	End If
	Resume Next
End Sub