Описание
Задает или возвращает максимальное число записей, возвращаемых в запросе.

Значение
Задаваемое или возвращаемое значение имеет тип данных Long, представляющее число возвращаемых записей. Значение по умолчанию 0 указывает, что число записей не ограничивается.

Замечания
Если в свойстве MaxRecords указано максимальное число строк, возвращаемых в приложении в объекте Recordset, процессор запроса прекращает возвращение записей в объекте Recordset, даже если имеются еще записи, подходящие для включения в набор записей. Данное свойство полезно в ситуациях, когда ограниченные ресурсы клиента не позволяют обрабатывать большое число записей.

Пример
Следующая программа использует свойство MaxRecords, чтобы установить предельное число записей, возвращаемых запросом к источнику данных ODBC.

Sub MaxRecordsX()

	Dim dbsCurrent As Database
	Dim qdfPassThrough As QueryDef
	Dim qdfLocal As QueryDef
	Dim rstTemp As Recordset

	' Открывает базу данных, в которой будет 
	' создан объект QueryDef.
	Set dbsCurrent = OpenDatabase("DB1.mdb")

	' Создает запрос к серверу для загрузки данных
	' из базы данных Microsoft SQL Server.
	Set qdfPassThrough = dbsCurrent.CreateQueryDef("")
	' Задает свойства нового запроса, ограничивающие 
	' возвращаемые записи числом 20.
	qdfPassThrough.Connect = "ODBC;DATABASE=pubs;UID=sa;PWD=;DSN=Publishers"
	qdfPassThrough.SQL = "SELECT * FROM titles"
	qdfPassThrough.ReturnsRecords = True
	qdfPassThrough.MaxRecords = 20

	Set rstTemp = qdfPassThrough.OpenRecordset()
	' Отображает результаты запроса.
	Debug.Print "Результаты запроса:"

	With rstTemp
		Do While Not .EOF
			Debug.Print , .Fields(0), .Fields(1)
			.MoveNext
		Loop
		.Close
	End With
	dbsCurrent.Close
End Sub