Добавляет объект в контейнер на этапе выполнения.

Применение
Column, CommandGroup, Объект Container, Custom, DataEnvironment, Form, FormSet, Grid, OptionGroup, Page, PageFrame, _SCREEN, ToolBar

Синтаксис

Object.AddObject(cName, cClass[, cOLEClass][, aInit1, aInit2...])

Параметры
cName
Задает имя, используемое для ссылки на новый объект.
cClass
Задает класс добавляемого объекта.
cOLEClass
Задает класс OLE добавляемого объекта.
aInit1, aInit2...
Задает параметры, передаваемые событию Init нового объекта.
Комментарии
Вызов метода AddObject инициирует событие Init в добавляемом объекте. Когда в объект FormSet добавляется Form, перед событием Init происходит событие Load.
Замечание! Когда вы используете метод AddObject для добавления объекта в контейнер, свойство Visible этого объекта принимает значение "ложь" (.F.), чтобы при установке свойств объекта изменение его внешнего вида не вызывало никаких нежелательных визуальных эффектов.

Пример:

* В следующем примере демонстрируется, как с помощью метода
* AddObject можно добавлять в форму объекты или элементы управления.
* В данном случае AddObject добавляет в форму элемент управления Line
* и три командные кнопки.
* Значение свойства Visible для элемента управления Line и для командных
* кнопок устанавливается равным "истине" (.T.). По умолчанию объекты и
* элементы управления, добавляемые в форму, являются невидимыми.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  && Create Command button
	Caption = 'Slant \<Up'  && Caption on the Command button
	Left = 50  && Command button column
	Top = 100  && Command button row
	Height = 25  && Command button height
	
	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.  && Hide the Line control
		ThisForm.shpLine.LineSlant ='/'  && Slant up
		ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
	Caption = 'Slant \<Down'  && Caption on the Command button
	Left = 200  && Command button column
	Top = 100  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.  && Hide the Line control
		ThisForm.shpLine.LineSlant ='\'  && Slant down
		ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 125  && Command button column
	Top = 150  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE