Для элементов управления задает положение левого края объекта относительно его родительского объекта. Для объектов Form определяет расстояние между левым краем формы и основным окном Visual FoxPro.

Применение:
CheckBox, ComboBox, CommandButton, CommandGroup, Объект Container, Объект Control, Custom, EditBox, Form, Grid, Image, Label, Line, ListBox, Связанный элемент управления OLE, Элемент управления OLE - контейнер, OptionButton, OptionGroup, PageFrame, _SCREEN, Shape, Spinner, TextBox, Timer, ToolBar.

Синтаксис:

Object.Left[ = nDist]

Установки:
nDist
Расстояние до левого края объекта-контейнера в единицах измерения, определенных свойством ScaleMode объекта Form.

Комментарии:
Доступно на этапе разработки и на этапе выполнения.
Используйте свойства Left, Top, Height и Width при выполнении операций, опирающихся на внешние размеры объекта, например при перемещении или изменении размера. Свойство ScaleMode позволяет изменить единицу измерения.
Замечание. Свойство Left доступно только для чтения, когда оно относится к элементу управления, содержащемуся в объекте Column.

Пример:

* Следующий пример демонстрирует, как использовать свойство Left для
* позиционирования элемента управления в форме. Метод AddObject
* используется для добавления в форму элемента управления Line и трех
* командных кнопок, а свойство Left задает горизонтальную позицию
* каждого из этих элементов управления в форме.
frmMyForm = CREATEOBJECT('Form')	&& Create a Form
frmMyForm.Closable = .F.	&& Disable the Control menu box

frmMyForm.AddObject('shpLine','Line')	&& Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')	&& Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')	&& Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')	&& Quit Cmnd button

frmMyForm.shpLine.Visible = .T.	&& Make Line control visible
frmMyForm.shpLine.Top = 20	&& Specify Line control row
frmMyForm.shpLine.Left = 125	&& Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.	&& Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.	&& Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.	&& Quit Command button visible

frmMyForm.SHOW	&& Display the form
READ EVENTS		&& Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON	&& Create Command button
	Caption = 'Slant \<Up'	&& Caption on the Command button
	Left = 50	&& Command button column
	Top = 100	&& Command button row
	Height = 25	&& Command button height
	
	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.	&& Hide the Line control
		ThisForm.shpLine.LineSlant ='/'	&& Slant up
		ThisForm.shpLine.Visible = .T.	&& Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton	&& Create Command button
	Caption = 'Slant \<Down'	&& Caption on the Command button
	Left = 200	&& Command button column
	Top = 100	&& Command button row
	Height = 25	&& Command button height

	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.	&& Hide the Line control
		ThisForm.shpLine.LineSlant ='\'	&& Slant down
		ThisForm.shpLine.Visible = .T.	&& Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton	&& Create Command button
	Caption = '\<Quit'	&& Caption on the Command button
	Cancel = .T.	&& Default Cancel Command button (Esc)
	Left = 125	&& Command button column
	Top = 150	&& Command button row
	Height = 25	&& Command button height

	PROCEDURE Click
		CLEAR EVENTS	&& Stop event processing, close Form
ENDDEFINE