www.ПЕРВЫЕ ШАГИ.ru :: Событие Click

Имеет место в следующих случаях:

Пользователь нажал и отпустил левую (главную) кнопку мыши при курсоре, указывающем на элемент управления, или изменил значение какого-либо элемента управления, или щелкнул пустую область формы.
Вы включили в программу код, инициирующий данное событие.

Применение:
CheckBox, ComboBox, CommandButton, CommandGroup, Объект Container, Объект Control, EditBox, Form, Grid, Header, Image, Label, Line, ListBox, OptionButton, OptionGroup, Page, PageFrame, Shape, Spinner, TextBox, ToolBar

Синтаксис:

PROCEDURE Object.Click
[LPARAMETERS nIndex]

Параметры:
nIndex
Однозначно идентифицирует элемент управления, если он принадлежит массиву элементов управления.

Комментарии:
Событие Click происходит, когда пользователь выполняет следующие действия:
Щелкает элемент управления CheckBox, CommandButton или OptionButton левой кнопкой мыши.
Выделяет элемент управления ComboBox или ListBox либо с помощью клавиш со стрелками, либо нажав кнопку мыши.
Нажимает клавишу SPACEBAR, когда в фокусе находится элемент управления CommandButton, OptionButton или CheckBox.
Нажимает клавишу ENTER, когда в объекте Form содержится элемент управления CommandButton, для которого свойство Default имеет значение "истина" (.T.).
Нажимает клавишу доступа некоторого элемента управления. Например, если элемент управления CommandButton имеет название "\<Go", то при нажатии клавиш ALT+G произойдет событие Click.
Щелкает пустую область объекта Form. События Click в форме не происходят, когда курсор указывает на строку заголовка, на кнопку управляющего меню или на рамку окна.
Щелкает область ввода текста в элементе управления Spinner.
Щелкает недоступный элемент управления. Событие Click происходит для формы с недоступным элементом управления.
Событие Click также возникает в результате действия включаемого вами кода, который:
Устанавливает для свойства Value элемента управления CommandButton значение "истина" (.T.).
Устанавливает для свойства Value элемента управления OptionButton значение "истина" (.T.) или 1.
Изменяет установку свойства Value элемента управления CheckBox.
Выдает команду MOUSE.

Пример:

* В следующем примере создается элемент управления OptionGroup и
* помещается в форму. Этот элемент управления имеет три кнопки. В
* зависимости от того, какую кнопку вы нажмете, появится окружность,
* эллипс или квадрат. Свойство ButtonCount используется для задания
* числа кнопок в элементе управления OptionGroup. Свойства Buttons и
* Caption используются, чтобы задать текст, появляющийся рядом с
* каждой кнопкой.
* Элемент управления Shape используется для создания окружности,
* эллипса и квадрата. Событие Click элемента управления OptionGroup
* использует структуру DO CASE ... ENDCASE и свойство Value, чтобы
* показать соответствующую фигуру, когда вы нажмете кнопку.

frmMyForm = CREATEOBJECT('Form')	&& Create a Form
frmMyForm.Closable = .F.	&& Disable the Control menu box

frmMyForm.AddObject('cmdCommand1','cmdMyCmndBtn')	&& Add Command button
frmMyForm.AddObject('opgOptionGroup1','opgMyOptGrp')	&& Add Option Group
frmMyForm.AddObject('shpCircle1','shpMyCircle')	&& Add Circle Shape
frmMyForm.AddObject('shpEllipse1','shpMyEllipse')	&& Add Ellipse Shape
frmMyForm.AddObject('shpSquare','shpMySquare')	&& Add Box Shape

frmMyForm.cmdCommand1.Visible =.T.	&& "Quit" Command button visible

frmMyForm.opgOptionGroup1.Buttons(1).Caption = "\<Circle"
frmMyForm.opgOptionGroup1.Buttons(2).Caption = "\<Ellipse"
frmMyForm.opgOptionGroup1.Buttons(3).Caption = "\<Square"
frmMyForm.opgOptionGroup1.SetAll("Width", 100)	&& Set Option group width
frmMyForm.opgOptionGroup1.Visible = .T.	&& Option Group visible
frmMyForm.opgOptionGroup1.Click	&& Show the circle

frmMyForm.SHOW	&& Display the form
READ EVENTS	&& Start event processing

DEFINE CLASS opgMyOptGrp AS OptionGroup	&& Create an Option Group
	ButtonCount = 3	&& Three Option buttons
	Top = 10
	Left = 10
	Height = 75
	Width = 100

	PROCEDURE Click 
		ThisForm.shpCircle1.Visible = .F.	&& Hide the circle
		ThisForm.shpEllipse1.Visible = .F.	&& Hide the ellipse
		ThisForm.shpSquare.Visible = .F.	&& Hide the square
		
		DO CASE
			CASE ThisForm.opgOptionGroup1.Value = 1
				ThisForm.shpCircle1.Visible = .T. 
					&& Show the circle
			CASE ThisForm.opgOptionGroup1.Value = 2 
				ThisForm.shpEllipse1.Visible = .T.  
					&& Show the ellipse
			CASE ThisForm.opgOptionGroup1.Value = 3 
				ThisForm.shpSquare.Visible = .T.  
					&& Show the square
		ENDCASE
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn AS CommandButton	&& Create Command button
	Caption = '\<Quit'	&& Caption on the Command button
	Cancel = .T.	&& Default Cancel Command button (Esc)
	Left = 125	&& Command button column
	Top = 210	&& Command button row
	Height = 25	&& Command button height

	PROCEDURE Click
		CLEAR EVENTS	&& Stop event processing, close Form
ENDDEFINE

DEFINE CLASS shpMyCircle AS SHAPE	&& Create a circle
	Top = 10
	Left = 200
	Width = 100
	Height = 100
	Curvature = 99
	BackColor = RGB(255,0,0)	&& Red
ENDDEFINE

DEFINE CLASS shpMyEllipse AS SHAPE	&& Create an ellipse
	Top = 35
	Left = 200
	Width = 100
	Height = 50
	Curvature = 99
	BackColor = RGB(0,128,0)	&& Green
ENDDEFINE

DEFINE CLASS shpMySquare AS SHAPE	&& Create a square
	Top = 10
	Left = 200
	Width = 100
	Height = 100
	Curvature = 0
	BackColor = RGB(0,0,255)	&& Blue
ENDDEFINE