Свойство LineSlant

Задает направление наклона линии из левого верхнего угла в правый нижний или из левого нижнего в правый верхний.

Применение:
Line.

Синтаксис:

Line.LineSlant[ = cSlant]

Установки:
cSlant
Для свойства LineSlant предусмотрены следующие установки:

Комментарии:
Доступно на этапе разработки и на этапе выполнения.

Пример:

* Следующий пример демонстрирует, как с помощью свойства LineSlant
* задавать направление наклона элемента управления Line.
* Элемент управления Line добавляется в форму. Туда же включаются три
* комадные кнопки, позволяющие изменять направление наклона линии, а
* также закрывать форму.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('shpLine','Line')  && Add a Line control to the form
frmMyForm.AddObject('cmdCmndBtn1','cmdMyCmndBtn1')  && Up Cmnd button
frmMyForm.AddObject('cmdCmndBtn2','cmdMyCmndBtn2')  && Down Cmnd button
frmMyForm.AddObject('cmdCmndBtn3','cmdMyCmndBtn3')  && Quit Cmnd button

frmMyForm.shpLine.Visible = .T.  && Make Line control visible
frmMyForm.shpLine.Top = 20  && Specify Line control row
frmMyForm.shpLine.Left = 125  && Specify Line control column

frmMyForm.cmdCmndBtn1.Visible =.T.  && Up Command button visible
frmMyForm.cmdCmndBtn2.Visible =.T.  && Down" Command button visible
frmMyForm.cmdCmndBtn3.Visible =.T.  && Quit Command button visible

frmMyForm.SHOW  && Display the form
READ EVENTS  && Start event processing

DEFINE CLASS cmdMyCmndBtn1 AS COMMANDBUTTON  && Create Command button
	Caption = 'Slant \<Up'  && Caption on the Command button
	Left = 50  && Command button column
	Top = 100  && Command button row
	Height = 25  && Command button height
	
	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.  && Hide the Line control
		ThisForm.shpLine.LineSlant ='/'  && Slant up
		ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn2 AS CommandButton  && Create Command button
	Caption = 'Slant \<Down'  && Caption on the Command button
	Left = 200  && Command button column
	Top = 100  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		ThisForm.shpLine.Visible = .F.  && Hide the Line control
		ThisForm.shpLine.LineSlant ='\'  && Slant down
		ThisForm.shpLine.Visible = .T.  && Show the Line control
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn3 AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 125  && Command button column
	Top = 150  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

Предыдущий Шаг | Следующий Шаг | Оглавление
Автор Каев Артем.