www.ПЕРВЫЕ ШАГИ.ru

Выполняет глагол для заданного объекта.

Применение:
Связанный элемент управления OLE, Элемент управления OLE - контейнер.

Синтаксис:

Object.DoVerb[Verb]

Параметры:
Verb
Назначенный к выполнению глагол объекта, входящего в элемент управления OLE Container. Если он не задан, выполняется глагол, принятый по умолчанию. В качестве данного аргумента может фигурировать один из стандартных глаголов, поддерживаемых всеми объектами, или индекс массива свойств ObjectVerbs. Каждый объект может поддерживать собственный набор глаголов. Приведенные ниже значения представляют стандартные глаголы, поддерживаемые всеми объектами:

0 - Действие, принимаемое по умолчанию для объекта.
-1 - Активизирует объект для выполнения редактирования. Если приложение, создавшее объект, поддерживает активизацию по месту, то объект активизируется прямо в элементе управления OLE Container.
-2 - Открывает объект в отдельном окне приложения. Если приложение, создавшее объект, поддерживает активизацию по месту, то объект активизируется в собственном окне.
-3 - В случае внедренных объектов скрывает приложение, создавшее объект.
-4 - Если объект поддерживает активизацию, он активизируется по месту и при этом отображаются все инструментальные средства пользовательского интерфейса. Если объект не поддерживает активизацию по месту, он не активизируется и возникает ошибка.
-5 - Если пользователь переводит фокус в элемент управления OLE Container, создается окно для объекта и объект подготавливается к редактированию. Если объект не поддерживает активизацию по щелчку мыши, возникает ошибка.
-6 - Используется при активизации объекта для редактирования, чтобы аннулировать весь протокол изменений, которые приложение объекта не в состоянии отменить.

Комментарии:
Если установить значение свойства AutoActivate равным 2 (DoubleClick), элемент управления OLE Container автоматически активизирует текущий объект, когда пользователь дважды щелкнет этот элемент управления.
Совет. Вы можете задавать глагол в методе DoVerb с помощью имени (edit, open, play и т.д.), но все же гораздо быстрее пользоваться индексом (0, 1, 2 и т.д.).

Пример:

* В следующем примере в форму добавляется элемент управления OLE
* Container, а свойства OleClass и DocumentFile используются, чтобы задать
* Excel в качестве OLE-сервера и определить электронную таблицу Excel в
* качестве редактируемого файла.
* Свойство DocumentFile определяет электронную таблицу BOOK1.XLS в
* каталоге EXCEL на диске C. Данный пример будет работать неправильно,
* если файл и каталог, заданные в свойстве DocumentFile, не существуют; в
* этом случае нужно модифицировать свойство DocumentFile, чтобы
* задать существующий файл электронной таблицы с каталогом.
* Метод DoVerb используется для активизации электронной таблицы при
* редактировании.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
frmMyForm.AddObject("oleObject","oleExcelObject")  && Add OLE object

frmMyForm.cmdCommand1.Visible=.T.  && Display the "Quit" Command button

frmMyForm.oleObject.Visible=.T.  && Display the OLE control
frmMyForm.oleObject.Height = 50  && OLE control height

frmMyForm.Show  && Display the Form

frmMyForm.oleObject.DoVerb(-1)  && -1 for Edit

READ EVENTS  && Start event processing

DEFINE CLASS oleExcelObject as OLEControl
	OleClass ="Excel.Sheet"  && Server name
	DocumentFile = "C:\EXCEL\BOOK1.XLS"  && This file must exist 
ENDDEFINE

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 125  && Command button column
	Top = 210  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE

Method DoVerb