Возвращает имя файла, на основе которого был создан внедренный или связанный объект.

Применение:
Связанный элемент управления OLE, Элемент управления OLE - контейнер.

Синтаксис:

Object.DocumentFile[ = cFileName]

Установки:
cFileName
Имя файла, из которого был создан внедренный или связанный объект.

Комментарии:
Доступно только для чтения на этапе разработки и на этапе выполнения.
Замечание. Свойство DocumentFile следует устанавливать в коде при создании OLE-объекта с помощью функции CREATEOBJECT( ).
Свойство DocumentFile можно также устанавливать в коде при создании OLE-объекта с помощью команды APPEND GENERAL.

Пример:

* В следующем примере в форму включается элемент управления OLE
* Container, а свойства DocumentFile и OleClass используются, чтобы задать
* электронную таблицу Excel в качестве редактируемого файла и
* определить Excel в качестве OLE-сервера.
* Свойство DocumentFile задает электронную таблицу BOOK1.XLS в
* каталоге EXCEL на диске C. Данный пример будет работать неправильно,
* если файл и каталог, заданные в свойствеDocumentFile, не существуют; в
* этом случае нужно модифицировать свойство DocumentFile, чтобы
* задать существующий файл электронной таблицы с каталогом.
* Для активизации электронной таблицы при редактировании используется
* метод DoVerb.

frmMyForm = CREATEOBJECT('Form')  && Create a Form
frmMyForm.Closable = .F.  && Disable the Control menu box 

frmMyForm.AddObject('cmdCommand1','cmdMyCmdBtn')  && Add Command button
frmMyForm.AddObject("oleObject","oleExcelObject")  && Add OLE object

frmMyForm.cmdCommand1.Visible=.T.  && Display the "Quit" Command button

frmMyForm.oleObject.Visible=.T.  && Display the OLE control
frmMyForm.oleObject.Height = 50  && OLE control height

frmMyForm.Show  && Display the Form

frmMyForm.oleObject.DoVerb(-1)  && -1 for Edit

READ EVENTS  && Start event processing

DEFINE CLASS oleExcelObject as OLEControl
	OleClass ="Excel.Sheet"  && Server name
	DocumentFile = "C:\EXCEL\BOOK1.XLS"  && This file must exist 
ENDDEFINE

DEFINE CLASS cmdMyCmdBtn AS CommandButton  && Create Command button
	Caption = '\<Quit'  && Caption on the Command button
	Cancel = .T.  && Default Cancel Command button (Esc)
	Left = 125  && Command button column
	Top = 210  && Command button row
	Height = 25  && Command button height

	PROCEDURE Click
		CLEAR EVENTS  && Stop event processing, close Form
ENDDEFINE