Свойства BackColor, ForeColor

Задают цвет фона и основной цвет символов, используемые при отображении текста и графики в объекте.

Применение:
CheckBox, Column, ComboBox, CommandButton, CommandGroup, Объект Container, Объект Control, EditBox, Form, Grid, Header, Label, OptionButton, OptionGroup, Page, _SCREEN, Shape, Spinner, TextBox, ToolBar

Замечание свойства BackColor не применяется к элементу управления CommandButton. Свойство ForeColor не применяется к элементам управления CommandGroup, OptionGroup и Shape.

Синтаксис:

Object.BackColor[ = nColor]
Object.ForeColor[ = nColor]

Установки:
nColor
Задает значение конкретного цвета. В следующей таблице перечислены типичные значения цветов.

Цвет			Значения RGB	Значение nColor
Белый			255, 255, 255	16777215
Черный			0, 0, 0		0
Серый			192, 192, 192	12632256
Темно-серый		128, 128, 128	8421504
Красный			255, 0, 0		255
Темно-красный		128, 0, 0		128
Желтый			255, 255, 0	65535
Темно-желтый		128, 128, 0	32896
Зеленый			0, 255, 0		65280
Темно-зеленый		0, 128, 0		32768
Голубой			0, 255, 255	16776960
Темно-голубой		0, 128, 128	8421376
Синий			0, 0, 255		16711680
Темно-синий		0, 0, 128		8388608
Фиолетовый		255, 0 ,255	16711935
Темно-фиолетовый		128, 0, 128	8388736

Комментарии:
Доступны на этапе разработки и на этапе выполнения.
В Visual FoxPro используется цветовая схема Windows "красный-зеленый-синий" (RGB). Красный, зеленый и синий компоненты представлены числовыми значениями из диапазона от 0 до 255. С помощью функции RGB( ) можно преобразовать эти три цветовые компонента в один комплексный индикатор nColor.
Свойство BackColor игнорируется, если свойство BackStyle имеет значение 0 (Transparent).

Пример:

* В следующем примере демонстрируется, как использовать элемент
* управления Shape, чтобы вывести в форму окружность, эллипс или
* квадрат; и как использовать свойство BackColor для задания цвета
* каждой фигуры.
* После создания формы, в нее помещается ряд переключателей и
* командная кнопка. Когда выбирается один из переключателей, в форме
* появляется соответствующая фигура. Свойство BackColor используется
* для задания цвета каждой фигуры. Свойства Height, Width, и Curvature
* определяют вид каждой создаваемой фигуры.

frmMyForm = CREATEOBJECT('Form')	&& Create a Form
frmMyForm.Closable = .F.	&& Disable the Control menu box

frmMyForm.AddObject('cmdCommand1','cmdMyCmndBtn')	&& Add Command button
frmMyForm.AddObject('opgOptionGroup1','opgMyOptGrp')	&& Add Option Group
frmMyForm.AddObject('shpCircle1','shpMyCircle')	&& Add Circle Shape
frmMyForm.AddObject('shpEllipse1','shpMyEllipse')	&& Add Ellipse Shape
frmMyForm.AddObject('shpSquare','shpMySquare')	&& Add Box Shape

frmMyForm.cmdCommand1.Visible =.T.	&& "Quit" Command button visible

frmMyForm.opgOptionGroup1.Buttons(1).Caption = "\<Circle"
frmMyForm.opgOptionGroup1.Buttons(2).Caption = "\<Ellipse"
frmMyForm.opgOptionGroup1.Buttons(3).Caption = "\<Square"
frmMyForm.opgOptionGroup1.SetAll("Width", 100)	&& Set Option group width
frmMyForm.opgOptionGroup1.Visible = .T.	&& Option Group visible
frmMyForm.opgOptionGroup1.Click	&& Show the circle

frmMyForm.SHOW	&& Display the form
READ EVENTS	&& Start event processing

DEFINE CLASS opgMyOptGrp AS OptionGroup	&& Create an Option Group
	ButtonCount = 3	&& Three Option buttons
	Top = 10
	Left = 10
	Height = 75
	Width = 100

	PROCEDURE Click 
		ThisForm.shpCircle1.Visible = .F.	&& Hide the circle
		ThisForm.shpEllipse1.Visible = .F.	&& Hide the ellipse
		ThisForm.shpSquare.Visible = .F.	&& Hide the square
		
		DO CASE
			CASE ThisForm.opgOptionGroup1.Value = 1
				ThisForm.shpCircle1.Visible = .T. 
					&& Show the circle
			CASE ThisForm.opgOptionGroup1.Value = 2 
				ThisForm.shpEllipse1.Visible = .T. 
					&& Show the ellipse
			CASE ThisForm.opgOptionGroup1.Value = 3 
				ThisForm.shpSquare.Visible = .T. 
					&& Show the square
		ENDCASE
ENDDEFINE

DEFINE CLASS cmdMyCmndBtn AS CommandButton	&& Create Command button
	Caption = '\<Quit'	&& Caption on the Command button
	Cancel = .T.	&& Default Cancel Command button (Esc)
	Left = 125	&& Command button column
	Top = 210	&& Command button row
	Height = 25	&& Command button height

	PROCEDURE Click
		CLEAR EVENTS	&& Stop event processing, close Form
ENDDEFINE

DEFINE CLASS shpMyCircle AS SHAPE	&& Create a circle
	Top = 10
	Left = 200
	Width = 100
	Height = 100
	Curvature = 99
	BackColor = RGB(255,0,0)	&& Red
ENDDEFINE

DEFINE CLASS shpMyEllipse AS SHAPE	&& Create an ellipse
	Top = 35
	Left = 200
	Width = 100
	Height = 50
	Curvature = 99
	BackColor = RGB(0,128,0)	&& Green
ENDDEFINE

DEFINE CLASS shpMySquare AS SHAPE	&& Create a square
	Top = 10
	Left = 200
	Width = 100
	Height = 100
	Curvature = 0
	BackColor = RGB(0,0,255)	&& Blue
ENDDEFINE

Предыдущий Шаг | Следующий Шаг | Оглавление
Автор Каев Артем.